Calcolo velocità e tempo di un percorso

Il problema

Punto primo

Dobbiamo stilare la classifica di una gara di equitazione, in particolare di una gara di endurance.

Abbiamo:

• un percorso di 25 Km
• la velocità massima stabilita è 12 Km/h
• la velocità minima stabilita è 8 Km/h

Trovare:

• il tempo necessario per completare il percorso alla velocità massima (tempo minimo accordato)
• il tempo necessario per completare il percorso alla velocità minima (tempo massimo accordato)

Punto secondo

Per ogni concorrente abbiamo:

• ora di partenza
• ora di arrivo
• frequenza cardiaca del cavallo alla fine della gara

Trovare:

• il tempo impiegato
• la velocità media (arrotondata al 3° decimale)
• la penalità
• il punteggio (arrotondato al 5° decimale)

Regole per il computo della penalità

• nessuna penalizzazione tra 12 Km/h ed 8 Km/h
• penalizzazione tra 12 Km/h e 12,5 Km/h e tra 7,5 Km/h e 8 Km/h
• squalifica oltre 12,5 Km/h e sotto 7,5 Km/h

Computo della penalità

• per velocità maggiori di 12 Km/h fino a 12,5 Km/h: il doppio della differenza tra il tempo minimo accordato e il tempo impiegato
• per velocità minori di 8 Km/h fino a 7,5 Km/h: il doppio della differenza tra il tempo impiegato e il tempo massimo accordato

Computo del punteggio

• (velocità del concorrente corretta per la penalità - velocità minima accordata) * 100 / frequenza cardiaca del cavallo

 

La soluzione

Questa è la tabella su cui andremo a lavorare:

	A	B	C	D	E	F	G	H	I	J
1	Lunghezza percorso Km:			25
2	Velocità massima Km/h:			12
3	Velocità minima Km/h:			8
4	Tempo minimo accordato:
5	Tempo massimo accordato:
6
7
8	Cavaliere	Ora Partenza	Ora Arrivo	Tempo Impiegato	Media (Km/h)	Penalità	Tempo Impiegato con penalità	Media (Km/h) con penalità	Battiti cardiaci	Punteggio
9
10	Cavaliere1	10.00.00	11.00.00						38
11	Cavaliere2	10.00.00	11.45.00						38
12	Cavaliere3	10.00.00	11.59.59						38
13	Cavaliere4	10.00.00	12.00.00						38
14	Cavaliere5	10.00.00	12.03.00						38

 

Punto primo

I tempi accordati

• il tempo necessario per completare il percorso alla velocità massima (tempo minimo accordato)
• il tempo necessario per completare il percorso alla velocità minima (tempo massimo accordato)

Il calcolo matematico è:

tempo = distanza / velocità ed il tempo deve essere espresso in Ore, Minuti, Secondi

Per la costruzione del tempo usiamo la funzione ORARIO che richiede questa sintassi:

ORARIO(ora;minuto;secondo) e che tradotto nel nostro caso diventa:

le ore	INT(D1/D2)
i minuti	INT(((D1/D2)-INT(D1/D2))*60)
i secondi	INT(((((D1/D2)-INT(D1/D2))*60)-INT(((D1/D2)- INT(D1/D2))*60))*60)

La formula completa è la seguente:

=ORARIO(INT(D1/D2);INT(((D1/D2)-INT(D1/D2))*60);INT(((((D1/D2)-INT(D1/D2))*60)- INT(((D1/D2)-INT(D1/D2))*60))*60;0))

Perciò nelle prime righe della nostra tabella avremo:

	A	B	C	D	E
1	Lunghezza percorso Km:			25
2	Velocità massima Km/h:			12
3	Velocità minima Km/h:			8
4	Tempo minimo accordato:			2.05.00
5	Tempo massimo accordato:			3.07.30

 

Secondo punto

Trovare il tempo impiegato per ogni concorrente (colonna D)

Questo è di facile soluzione. Conoscendo l'ora di partenza e l'ora di arrivo si esegue semplicemente:

=C10-B10

oppure, se si prevede che occorra fare dei conteggi su orari a cavallo della mezzanotte:

=C10-B10+(C10<B10)*24

Finora questa è la situazione che ci si presenta:

	A	B	C	D
7
8	Cavaliere	Ora Partenza	Ora Arrivo	Tempo Impiegato
9
10	Cavaliere1	10.00.00	11.00.00	1.00.00	=C10-B10
11	Cavaliere2	10.00.00	11.45.00	1.45.00	=C11-B11
12	Cavaliere3	10.00.00	11.59.59	1.59.59	=C12-B12
13	Cavaliere4	10.00.00	12.00.00	2.00.00	=C13-B13
14	Cavaliere5	10.00.00	12.03.00	2.03.00	=C14-B14

 

Trovare la velocità impiegata per compiere il percorso (colonna E)

Il calcolo matematico è:

velocità = distanza / tempo

Le formule possibili sono due:

=($D$1/(ORA(D13)*60*60+MINUTO(D13)*60+SECONDO(D13)))*60*60

oppure

=($D$1/D10)/24

Siccome sono equivalenti si può decidere di usare la seconda che è più semplice perciò questa la nuova situazione:

	A	B	C	D	E
8	Cavaliere	Ora Partenza	Ora Arrivo	Tempo Impiegato	Media (Km/h)
9
10	Cavaliere1	10.00.00	11.00.00	1.00.00	25,000	=($D$1/D10)/24
11	Cavaliere2	10.00.00	11.45.00	1.45.00	14,286	=($D$1/D11)/24
12	Cavaliere3	10.00.00	11.59.59	1.59.59	12,502	=($D$1/D12)/24
13	Cavaliere4	10.00.00	12.00.00	2.00.00	12,500	=($D$1/D13)/24
14	Cavaliere5	10.00.00	12.03.00	2.03.00	12,195	=($D$1/D14)/24

 

Calcolo della penalità (colonna F)

A questo punto dobbiamo valutare queste situazioni:

• nessuna penalizzazione tra 12 Km/h ed 8 Km/h
• penalizzazione tra 12 Km/h e 12,5 Km/h e tra 7,5 Km/h e 8 Km/h
• squalifica oltre 12,5 Km/h e sotto 7,5 Km/h

Questa verifica va segnalata nella colonna Penalità (colonna F)

1. se la velocità indicata nella colonna E è superiore a 12,5 o inferiore a 7,5 il concorrente viene squalificato
   1. SE(E10>($D$2+0,5);"eliminato";SE(E10<($D$3-0,5);"eliminato";......
2. se la velocità indicata nella colonna E è superiore a 12 o inferiore a 8 (per aver superato il primo test è ovvio che si sta valutando una velocità compresa tra 12 e 12,5 o tra 8 ed 8,5) viene calcolata la penalità. La penalità viene calcolata raddoppiando il tempo extra con la formula ($D$4-D10)*2 oppure (D10-$D$5)*2
   1. SE(E10>$D$2;(($D$4-D10)*2);SE(E10<$D$3;((D10-$D$5)*2);
3. se nessuna delle due condizioni risulta vera vi è 0 (zero) penalità
   1. "0")))) con chiusura di tutti i SE

Questa la formula completa:

=SE(E10>($D$2+0,5);"eliminato";SE(E10<($D$3-0,5);"eliminato";SE(E10>$D$2;(($D$4-D10)*2);SE(E10<$D$3;((D10-$D$5)*2);"0"))))

Lo schema di questa istruzione è questa qui sotto:

	test	se vero	se falso
=SE(	E15>($D$2+0,5);	eliminato;	SE(E10<($D$3-0,5); "eliminato"; SE(E10>$D$2; (($D$4-D10)*2); SE(E10<$D$3; ((D10-$D$5)*2); "0")))	vedi sotto
		test	se vero	se falso
	SE(	E15<($D$3-0,5);	eliminato;	SE(E10>$D$2; (($D$4-D10)*2); SE(E10<$D$3; ((D10-$D$5)*2); "0"))	vedi sotto
			test	se vero	se falso
		SE(	E15>$D$2;	(($D$4-D15)*2);	SE(E10<$D$3; ((D10-$D$5)*2); "0")	vedi sotto
				test	se vero	se falso
			SE(	E15<$D$3;	((D15-$D$5)*2);	0

 

La situazione dovrebbe essere la seguente:

	A	B	C	D	E	F
8	Cavaliere	Ora Partenza	Ora Arrivo	Tempo Impiegato	Media (Km/h)	Penalità
9
10	Cavaliere 1	10.00.00	11.00.00	1.00.00	25,000	eliminato
11	Cavaliere 2	10.00.00	11.45.00	1.45.00	14,286	eliminato
12	Cavaliere 3	10.00.00	11.59.59	1.59.59	12,502	eliminato
13	Cavaliere 4	10.28.00	12.31.14	2.03.14	12,172	0.03.32
14	Cavaliere 5	10.12.00	12.16.56	2.04.56	12,006	0.00.08
	Nella colonna F va la formula:
	=SE(E10>($D$2+0,5);"eliminato";SE(E10<($D$3-0,5);"eliminato";SE(E10>$D$2; (($D$4-D10)*2); SE(E10<$D$3;((D10-$D$5)*2);"0"))))

 

Riepilogo dei tempi impiegati comprensivi di penalità (colonna G)

In questa colonna viene trascritto il tempo impiegato solo se il tempo è netto o se è penalizzato. In caso di squalifica viene scritto un trattino.

Questa la formula impiegata:

=SE(F10="eliminato";" - ";(D10+F10))

Oramai questa formula è semplicissima e non merita altri commenti.

La nuova situazione è questa:

	A	B	C	D	E	F	G
8	Cavaliere	Ora Partenza	Ora Arrivo	Tempo Impiegato	Media (Km/h)	Penalità	Tempo Impiegato con penalità
9
10	Cavaliere 1	10.00.00	11.00.00	1.00.00	25,000	eliminato	-
11	Cavaliere 2	10.00.00	11.45.00	1.45.00	14,286	eliminato	-
12	Cavaliere 3	10.00.00	11.59.59	1.59.59	12,502	eliminato	-
13	Cavaliere 4	10.28.00	12.31.14	2.03.14	12,172	0.03.32	2.06.46
14	Cavaliere 5	10.12.00	12.16.56	2.04.56	12,006	0.00.08	2.05.04
	Nella colonna G la formula
	=SE(F10="eliminato";" - ";(D10+F10))

 

Riepilogo dela media della velocità comprensiva di penalità (colonna H)

In questa colonna viene calcolata la velocità media corretta in base alla penalità del concorrente. La formula è la stessa usata per calcolare la velocità media nella colonna E.

Anche in questo caso se il soggetto è stato squalificato (colonna F) non viene eseguito nessun calcolo e viene scritto un trattino.

La formula è la seguente:

=SE(F10="eliminato";" - ";ARROTONDA(($D$1/G10)/24;3))

A questo punto ecco la nuova situazione:

 

	A	B	C	D	E	F	G	H
1	Lunghezza percorso Km:			25
2	Velocità massima Km/h:			12
3	Velocità minima Km/h:			8
4	Tempo minimo accordato:
5	Tempo massimo accordato:
6
7
8	Cavaliere	Ora Partenza	Ora Arrivo	Tempo Impiegato	Media (Km/h)	Penalità	Tempo Impiegato con penalità	Media (Km/h) con Penalità
9
10	Cavaliere 1	10.00.00	11.00.00	1.00.00	25,000	eliminato	-	-
11	Cavaliere 2	10.00.00	11.45.00	1.45.00	14,286	eliminato	-	-
12	Cavaliere 3	10.00.00	11.59.59	1.59.59	12,502	eliminato	-	-
13	Cavaliere 4	10.28.00	12.31.14	2.03.14	12,172	0.03.32	2.06.46	11,833
14	Cavaliere 5	10.12.00	12.16.56	2.04.56	12,006	0.00.08	2.05.04	11,994
	Nella colonna H la formula
	=SE(F10="eliminato";" - ";ARROTONDA(($D$1/G10)/24;3))

 

Il punteggio (colonna J)

Finalmente l'ultimo dei calcoli.

Per il computo del punteggio eseguiamo:

(velocità del concorrente corretta per la penalità - velocità minima accordata) * 100 / frequenza cardiaca del cavallo

con la seguente formula:

=SE(F10="eliminato";" - ";ARROTONDA((H10-$D$3)*100/I10;5))

Se nella colonna F il concorrente è già stato squalificato si scrive il solito trattino, in caso contrario viene effettuato il calcolo.

 

	A	B	C	D	E	F	G	H	I	J
1	Lunghezza percorso Km:			25
2	Velocità massima Km/h:			12
3	Velocità minima Km/h:			8
4	Tempo minimo accordato:
5	Tempo massimo accordato:
6
7
8	Cavaliere	Ora Partenza	Ora Arrivo	Tempo Impiegato	Media (Km/h)	Penalità	Tempo Impiegato con penalità	Media (Km/h) con penalità	Battiti cardiaci	Punteggio
9
10	Cavaliere 1	10.00.00	11.00.00	1.00.00	25,000	eliminato	-	-	38	-
11	Cavaliere 2	10.00.00	11.45.00	1.45.00	14,286	eliminato	-	-	38	-
12	Cavaliere 3	10.00.00	11.59.59	1.59.59	12,502	eliminato	-	-	38	-
13	Cavaliere 4	10.28.00	12.31.14	2.03.14	12,172	0.03.32	2.06.46	11,833	44	8,71136
14	Cavaliere 5	10.12.00	12.16.56	2.04.56	12,006	0.00.08	2.05.04	11,994	48	8,32083
	Nella colonna J la formula
	=SE(F10="eliminato";" - ";ARROTONDA((H10-$D$3)*100/I10;5))

 

Conclusioni

Per la soluzione di questo problema ho trovato un valido aiuto da Raffaella Butera che voglio ringraziare per la sua preziosa collaborazione.